excel countif函數(shù)怎么用 COUNTIF函數(shù)用法總結(jié)，這個(gè)問題是我們很多人都很困惑的一個(gè)問題，excel countif函數(shù)怎么用是我們非常常用的一個(gè)東西，也是我們工作和學(xué)習(xí)中必不可少的一個(gè)數(shù)據(jù)公式，那么具體我們要怎么做呢？下面就來看看這篇excel countif函數(shù)怎么用 COUNTIF函數(shù)用法總結(jié)的文章吧！

一、求各種類型單元格的個(gè)數(shù)

(1) 求真空單元格單個(gè)數(shù): =COUNTIF(data,"=")

(2) 真空+假空單元格個(gè)數(shù): =COUNTIF(data,"") 相當(dāng)于countblank()函數(shù)

(3) 非真空單元格個(gè)數(shù): =COUNTIF(data,"<>") 相當(dāng)于counta()函數(shù)

(4) 文本型單元格個(gè)數(shù): =COUNTIF(data,"*") 假空單元格也是文本型單元格

(5) 區(qū)域內(nèi)所有單元格個(gè)數(shù): =COUNTIF(data,"<>""")

(6) 邏輯值為TRUE的單元格數(shù)量 =COUNTIF(data,TRUE)

小說明：

EXCEL單元格內(nèi)數(shù)據(jù)主要有以下幾類:數(shù)值型,文本型,邏輯型,錯(cuò)誤值型。其中時(shí)間類型也是一種特殊的數(shù)值。文本類型的數(shù)字是文本型。

空單元格：指什么內(nèi)容也沒有的單元格，姑且稱之為真空。

假空單元格：指0字符的空文本，一般是由網(wǎng)上下載來的或公式得來的，姑且稱之為假空。

date指單元格區(qū)域，該參數(shù)不能是數(shù)組

二、求><=某個(gè)值的單元格個(gè)數(shù)

(1) 大于50 =COUNTIF(data,">50")

(2) 等于50 =COUNTIF(data,50)

(3) 小于50 =COUNTIF(data,"<50")

(4) 大于或等于50 =COUNTIF(data,">=50")

(5) 小于或等于50 =COUNTIF(data,"<=50") ¬

(6) 大于E5單元格的值 =COUNTIF(data,">"&$E$5)

(7) 等于E5單元格的值 =COUNTIF(data,$E$5)

(8) 小于E5單元格的值 =COUNTIF(data,"<"&$E$5)

(9) 大于或等于E5單元格的值 =COUNTIF(data,">="&$E$5)

(10) 小于或等于E5單元格的值 =COUNTIF(data,"<="&$E$5)

三、等于或包含某N個(gè)特定字符的單元格個(gè)數(shù)

(1) 兩個(gè)字符 =COUNTIF(data,"??")

(2) 兩個(gè)字符并且第2個(gè)是B =COUNTIF(data,"?B")

(3) 包含B =COUNTIF(data,"*B*")

(4) 第2個(gè)字符是B =COUNTIF(data,"?B*")

(5) 等于“你好” =COUNTIF(data,"你好")

(6) 包含D3單元格的內(nèi)容 =COUNTIF(data,"*"&D3&"*")

(7) 第2字是D3單元格的內(nèi)容 =COUNTIF(data,"?"&D3&"*")

注：countif()函數(shù)對(duì)英文字母不區(qū)分大小寫，通配符只對(duì)文本有效

四、兩個(gè)條件求個(gè)數(shù)

(1) >10并且<=15 =SUM(COUNTIF(data,">"&{10,15})*{1,-1})

(2) >=10并且<15 =SUM(COUNTIF(data,">="&{10,15})*{1,-1})

(3) >=10并且<=15 =SUM(COUNTIF(data,{">=10",">15"})*{1,-1})

(4) >10并且<15 =SUM(COUNTIF(data,{">10",">=15"})*{1,-1})

注：一般多條件計(jì)數(shù)使用SUMPRODUCT函數(shù)，以上方法較少使用，僅供參考。

補(bǔ)充：三個(gè)區(qū)域計(jì)數(shù)：

三個(gè)區(qū)域中>=60 =SUM(COUNTIF(INDIRECT({"a46:a48","b48:b50","c47:c48"}),">=60"))

五、各種特殊統(tǒng)計(jì)要求的計(jì)算 A2：A32 為存放數(shù)據(jù)的區(qū)域

(1)非空文本(僅包括可鍵入文本) =COUNTIF(A2:A32,">=!")

(2)所有非空文本 =COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">="&CHAR(1))-COUNTIF(A2:A32,">= ") 或 {=SUM(COUNTIF(A2:A32,">="&{"!"," "})*{1,-1})+COUNTIF(A2:A32,">="&CHAR(1))}

(3)全部可見單元格 {=SUM(N(IF(ISERROR(A2:A32),1,SUBSTITUTE(A2:A32," ",""))<>""))}

(4)有效可見單元格 =COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">="&CHAR(1))-COUNTIF(A2:A32,">= ")+COUNT(A2:A32)

(5)全部不見單元格(真空+空格+空文本) =COUNTIF(A2:A32,"")-COUNTIF(A2:A32,">=!")+COUNTIF(A2:A32,">= ")

(6)空格 =COUNTIF(A2:A32,">= ")-COUNTIF(A2:A32,">=!")

(7)空文本"" =COUNTIF(A2:A32,"")-COUNTIF(A2:A32,"=")

(8)邏輯與錯(cuò)誤 =COUNTIF(A2:A32,"<>")-COUNTIF(A2:A32,"*")-COUNT(A2:A32)