excel VLOOKUP逆向查詢，記住這些才是真的會了,近日有關(guān)世界杯的新聞太多，大家是不是都目不暇接了？不要留戀，還是默默的學點技術(shù)吧，比如“excel VLOOKUP”這一干貨技術(shù)是excel VLOOKUP逆向查詢，記住這些才是真的會了來實現(xiàn)這一技術(shù)，快跟小編來了解一下這個實用技能吧~

在日常的Excel函數(shù)應用中，最常用的就是查詢類函數(shù)，比如說根據(jù)工號查詢姓名、根據(jù)學生查詢成績、根據(jù)男豬腳查詢女一號等等。

說到查詢類函數(shù)，大家對VLOOKUP一定不會陌生，這可是人見人愛花見花開的函數(shù)。

下面這個圖中，就是根據(jù)工號查詢姓名的典型應用：

G2單元格公式為

=VLOOKUP(F2,A2:D10,2,0)

意思就是以F2單元格的工號作為查詢值，以A2:D10為查找區(qū)域，在首列中找到與F2單元格相同的工號，然后返回這個區(qū)域中與之對應的第二列（也就是姓名所在列）的姓名。

如果我們以姓名作為查找值，需要在這個區(qū)域中查找和姓名對應的工號，該如何使用公式呢？

因為VLOOKUP函數(shù)要求查詢值必須處于查詢區(qū)域的首列，再使用普通方法就無法完成要求了，今天就和大家說說，關(guān)于逆向查詢的幾種方法。

方法一

使用IF函數(shù)重新構(gòu)建數(shù)組。

G2使用公式為：

=VLOOKUP(F2,IF({1,0},B2:B10,A2:A10),2,0)

這個公式的用法在之前的內(nèi)容中咱們曾經(jīng)講過，就是用IF({1,0},B2:B10,A2:A10)，返回一個姓名在前，工號在后的多行兩列的內(nèi)存數(shù)組，使其符合VLOOKUP函數(shù)的查詢值處于查詢區(qū)域首列的條件，再用VLOOKUP查詢即可。

該函數(shù)使用比較復雜，運算效率低。

裝逼指數(shù)：★★★★★

推薦指數(shù)：★

方法二

使用CHOOSE函數(shù)重新構(gòu)建數(shù)組。

G2使用公式為：

=VLOOKUP(F2,CHOOSE({1,2},B2:B10,A2:A10),2,0)

這個公式的原理也是重新構(gòu)建一個內(nèi)存數(shù)組，使其符合VLOOKUP函數(shù)的查詢值處于查詢區(qū)域首列的條件。

該函數(shù)與方法一的思路相同，同樣是使用復雜，運算效率低。

裝逼指數(shù)：★★★★★

推薦指數(shù)：★

方法三

INDEX+MATCH結(jié)合使用。

G2使用公式為：

=INDEX(A2:A10,MATCH(F2,B2:B10,))

公式首先使用MATCH函數(shù)返回F2單元格姓名在B2:B10單元格中的相對位置6，也就是這個區(qū)域中所處第幾行。

再以此作為INDEX函數(shù)的索引值，從A2:A10單元格區(qū)域中返回對應位置的內(nèi)容。

這個公式是最常用的查詢公式之一，看似繁瑣，實際查詢應用時，由于其組合靈活，可以完成從左至右、從右到左、從下到上、從上到下等多個方向的查詢。

該函數(shù)是嵌套使用，操作靈活，運算方便。

裝逼指數(shù)：★★★

推薦指數(shù)：★★★

方法四

所向披靡的LOOKUP函數(shù)。

G2使用公式為：

=LOOKUP(1,0/(F2=B2:B10),A2:A10)

這是非常經(jīng)典的LOOKUP用法。

首先用F2=B2:B10得到一組邏輯值，再用0除以這些邏輯值，得到由0和錯誤值組成的內(nèi)存數(shù)組。再用1作為查詢值，在內(nèi)存數(shù)組中進行查詢。

如果LOOKUP函數(shù)找不到查詢值，則它與查詢區(qū)域中小于或等于查詢值的最大值匹配，因此是以最后一個0進行匹配，并返回A2:A10中相同位置的值。

該函數(shù)使用簡便，功能強大，公式書寫也比較簡潔。

裝逼指數(shù)：★

推薦指數(shù)：★★★★★

如果有多條符合條件的結(jié)果，前三個公式都是返回首個滿足條件的值，而第四個公式則是返回最后一個滿足條件的值，這一點大家在使用時還需要特別注意。